For network or hard drive access the FamilySearch directory can be configured as shown below. CD data is copied to the respective folders which can be stored on different systems. Each of the seven top level folders is shared. The Folder Sharing section of the Resource Sharing page has more information on folder sharing.

The structure of the IGI and the IGI-Addendum (ad) directories is identical.

IGI directory structure showing files in North America folder.

Network installation should be preceded by a successful CD-ROM installation. Run the FS setup.exe and specify installation type A to complete a CD-based installation.

After testing the C:\PAS directory should be renamed C:\PAS-CD for installations of the Network Client with CD Backup configuration described below.

For network and local drive access FS setup.exe is executed with the network option.

Executing FS setup with the network option.

IE float bug

Each FS component application is assigned an unused logical drive letter. They can be specified in the Network Installation window shown below.

FS network shares can be assigned in the Network Installation dialog.

IE float bug

Installation option B is selected for network installation.

The DOS installation procedure uses the drive letters specified in the Network Installation window as the default drive types. The types can be modified to create a mix of local and network resources as shown in the Hybrid Client section.

The CD (platter) locations are initialized to the values of the Network Installation parameters. Drive letter customization is possible but should not be necessary.

The remainder of the network installation procedure is identical to the CD setup.

Before FS can be tested the logical drives N-T must be associated with data sources. Local drives are substituted via the DOS Subst command shown in the substdrive.bat batch file below.

Note: Windows Me, 2K, and XP do not process substitute commands in the autoexec.bat file. They can be grouped in a batch file and executed from the Programs > StartUp folder. The vSubst utility program can also substitute drives on Me, 2K, and XP however it should only be used for local folders.

::******************** file: substdrive.bat *******************

:: v. 4/2001
:: This bat file connects local drive data using the DOS Subst
:: command. It can be configured to execute by clicking the FS shortcut
:: on the patron desktop.

:: Variables
:: <local drive path> is the path to disk data, e.g. D:\fsdata
:: Drives N: through T: are associated with local drive folders
:: C:\PAS is the path to the PAS directory on the client

@echo off

:: local drive substitutions

subst n: <local drive path>\af
subst o: <local drive path>\lc
subst p: <local drive path>\igi
subst q: <local drive path>\ad
subst r: <local drive path>\scr
subst s: <local drive path>\ss
subst t: <local drive path>\mi

::execute PAS
C:\PAS\PAS.EXE

Network drives can be mapped by right clicking My Computer and selecting Map Network Drive... or via the mapdrive.bat batch file below. More information on drive mapping is in the Share Access section on the Resource Sharing page. The DOS net use command is described on the Management Resources page.

::******************** file: mapdrive.bat *******************

:: v. 4/2001
:: This bat file connects network resources using the DOS Net Use
:: command. It can be configured to execute by clicking the FS shortcut
:: on the patron desktop.

:: Variables
:: Server is name of the FamilySearch file server
:: Drives N: through T: are mapped to shares on the file server
:: c:\pas is the path to the PAS directory on the client

@echo off

:: network mappings

net use n: \\Server\af$ /yes
net use o: \\Server\lc$ /yes
net use p: \\Server\igi$ /yes
net use q: \\Server\ad$ /yes
net use r: \\Server\scr$ /yes
net use s: \\Server\ss$ /yes
net use t: \\Server\mi$ /yes

::execute PAS

C:\PAS\PAS.EXE

The relationships between the FS data folders on drive ß:\ and the logical drives is shown below:

FamilySearch can be configured to operate with a mix of network and CD-ROM data. Drive letters can be specified in the Network Installation window if FS setup.exe is executed with the network option. In the capture below AF, LC, IGI and IGI-Addendum are assigned unused logical drive letters. SCR, SS, and MI are assigned the CD-ROM drive letter.

Hybrid FamilySearch network installation that mixes server and CD data.

IE float bug

Installation option B is selected for hybrid installation.

The DOS installation procedure uses the drive letters specified in the Network Installation window as the default drive types. For hybrid operation the types must be modified to distinguish CD-ROM and network resources. In the capture below the drive type of drive Y, the local CD-ROM, has been changed from <Network> to <Drawer/Tray> to configure it as a local CD-ROM data source.

Before FS can be tested the logical drives N-Q must be associated with data sources. Please refer to the preceding discussion for information on batch files to perform local and network drive substitutions.

Some degree of redundancy should be considered for FS installations. In the following configuration two sets of FS configuration files, one for network operation and one for CD-ROM operation, are stored on the client. The availability of network resources determines how FS is configured at run-time by a batch file, testnet.bat.

The configuration parameters for FS are stored in 14 files:

pas.ini	\igi\regions.tbl	\tr\rgns1.tbl
pasetup.txt	\igi\regions.add	\tr\rgns1.bak
\af\plat2net.tbl	\oi\regions.tbl	\tr\regions.tbl
\af\plat2net.bak	\oi\regions.add	\tr\regions.bak
\scr\regions.tbl	\ss\platter.txt

These files are saved in a new subdirectory \PAS\PASCONFIG. One set is copied from a CD-based installation, the PAS-CD folder, and stored in PAS\PASCONFIG\CD. The other set is copied from a network installation and stored in PAS\PASCONFIG\NET.

FamilySearch configuration directory (PASCONFIG) structure.

IE float bug

The contents of the \pasconfig\net and \pasconfig\net\tr subdirectories are shown in the screen captures below:

To determine the start-up configuration FamilySearch is executed via a batch file, testnet.bat, that tests for the existence of FS files on a server. If found the network configuration files are copied from the \pasconfig\net\ subdirectory to the PAS folder and FS is configured for network operation. If not found the CD configuration files are copied from \pasconfig\cd\ to the PAS folder and FS is configured for CD operation.

The screen capture below shows the output when network data is unavailable.

::********************* testnet.bat ***********************

:: 5/2001 2.27 test
:: This bat file can be configured to execute by clicking the FS shortcut
:: on the patron desktop. It tests for the existence of FS files on a server.
:: If found FS is configured for file server operation,
:: if not FS is configured for CD operation.

:: Variables
:: server is the name of the FamilySearch file server
:: Drives N: through T: refer to the FS directories on the file server
:: c:\pas is the path to the PAS directory on the client

:: Setup
:: The c:\pas\pasconfig\ directory stores the FS configuration files.
:: c:\pas\pasconfig\cd\ is the subdirectory for cd configuration files
:: c:\pas\pasconfig\net\ is the subdirectory for network configuration files
:: These files contain the configuration dependent information for FS.
:: They were copied from two FS installations, one for CD operation,
:: the other for network operation.
:: The c:\pas\pasconfig\ directory is approx 220 KB

:: Output
:: use.cd or use.net is written to the c:\pas\paconfig\ directory
:: to indicate the FS configuration and the appropriate set of
:: configuration files is copied from \pas\pasconfig to the \pas directory
:: if necessary.

@echo off

:: verify network connections

echo Please wait, FamilySearch is looking for network data...

net use n: \\server\af$ /yes
net use | find "OK" > NUL
if errorlevel 1 goto :usecd

net use o: \\server\lc$ /yes
net use | find "LC$" > NUL
if errorlevel 1 goto :usecd

net use p: \\server\igi$ /yes
net use | find "IGI$" > NUL
if errorlevel 1 goto :usecd

net use q: \\server\ad$ /yes
net use | find "AD$" > NUL
if errorlevel 1 goto :usecd

net use r: \\server\scr$ /yes
net use | find "SCR$" > NUL
if errorlevel 1 goto :usecd

net use s: \\server\ss$ /yes
net use | find "SS$" > NUL
if errorlevel 1 goto :usecd

net use t: \\server\mi$ /yes
net use | find "MI$" > NUL
if errorlevel 1 goto :usecd

ECHO all drives mapped
If EXIST N:\Af_vocab GOTO :fileserver

:usecd

If EXIST c:\pas\pascon~1\use.cd GOTO :cdfiles

copy c:\pas\pascon~1\cd\pas.ini c:\pas\pas.ini
copy c:\pas\pascon~1\cd\pasetup.txt c:\pas\pasetup.txt

copy c:\pas\pascon~1\cd\tr\rgns1.tbl c:\pas\tr\rgns1.tbl
copy c:\pas\pascon~1\cd\tr\rgns1.bak c:\pas\tr\rgns1.bak
copy c:\pas\pascon~1\cd\tr\regions.tbl c:\pas\tr\regions.tbl
copy c:\pas\pascon~1\cd\tr\regions.bak c:\pas\tr\regions.bak

copy c:\pas\pascon~1\cd\scr\regions.tbl c:\pas\scr\regions.tbl

copy c:\pas\pascon~1\cd\ss\platter.txt c:\pas\ss\plattter.txt

copy c:\pas\pascon~1\cd\oi\regions.tbl c:\pas\oi\regions.tbl
copy c:\pas\pascon~1\cd\oi\regions.add c:\pas\oi\regions.add

copy c:\pas\pascon~1\cd\igi\regions.tbl c:\pas\igi\regions.tbl
copy c:\pas\pascon~1\cd\igi\regions.add c:\pas\igi\regions.add

copy c:\pas\pascon~1\cd\af\plat2net.tbl c:\pas\af\plat2net.tbl
copy c:\pas\pascon~1\cd\af\plat2net.bak c:\pas\af\plat2net.bak

::create use.cd file to signal cd configuration
echo cd files loaded > c:\pas\pascon~1\use.cd
del c:\pas\pascon~1\use.net

:cdfiles
echo.
echo we're sorry...it looks like network data is currently unavailable,

echo FamilySearch will be configured to operate with CD data.
echo Please notify the system administrator, thank you.
echo.
pause
GOTO :end

:fileserver

If EXIST c:\pas\pascon~1\use.net GOTO :netfiles

copy c:\pas\pascon~1\net\pas.ini c:\pas\pas.ini
copy c:\pas\pascon~1\net\pasetup.txt c:\pas\pasetup.txt

copy c:\pas\pascon~1\net\tr\rgns1.tbl c:\pas\tr\rgns1.tbl
copy c:\pas\pascon~1\net\tr\rgns1.bak c:\pas\tr\rgns1.bak
copy c:\pas\pascon~1\net\tr\regions.tbl c:\pas\tr\regions.tbl
copy c:\pas\pascon~1\net\tr\regions.bak c:\pas\tr\regions.bak

copy c:\pas\pascon~1\net\scr\regions.tbl c:\pas\scr\regions.tbl

copy c:\pas\pascon~1\net\ss\platter.txt c:\pas\ss\plattter.txt

copy c:\pas\pascon~1\net\oi\regions.tbl c:\pas\oi\regions.tbl
copy c:\pas\pascon~1\net\oi\regions.add c:\pas\oi\regions.add

copy c:\pas\pascon~1\net\igi\regions.tbl c:\pas\igi\regions.tbl
copy c:\pas\pascon~1\net\igi\regions.add c:\pas\igi\regions.add

copy c:\pas\pascon~1\net\af\plat2net.tbl c:\pas\af\plat2net.tbl
copy c:\pas\pascon~1\net\af\plat2net.bak c:\pas\af\plat2net.bak

::create use.net file to signal file server configuration

echo network files loaded > c:\pas\pascon~1\use.net
del c:\pas\pascon~1\use.cd

:netfiles

:end
C:\PAS\PAS.EXE

The FamilySearch Properties window can be opened by right-clicking the FS desktop shortcut and selecting Properties.

Batch files substdrive.bat, mapdrive.bat, and testnet.bat can be configured to execute from the PAS shortcut on the desktop. Select the Program tab, and enter the batch file path in the Command line.

Batch file startup specified in FamilySearch program properties Command line.

IE float bug

Other parameters can also be specified in the FamilySearch Properties window. If necessary, the amount of EMS memory can be specified by selecting the Memory tab and selecting a Total value.

EMS Memory setting in the Memory Properties dialog.

IE float bug

FS's default configuration is full-screen. It can be set to operate in a window through a parameter accessible via the Screen tab on the FamilySearch Properties menu.

FamilySearch window size setting in the Screen Properties dialog.